其中比較難解決的問題就是獲取網絡連線的實際名稱,大部分人使用的IP設置腳本都是將【本地連接】寫死在代碼中，可實際上并不是所有電腦都叫本地連接；比如有的用戶電腦可能升級了網卡驅動，或者更換了網卡，導致網絡連線的名稱變成“本地連接2”，又比如有無聊好事者(某產線的作業(yè)員電腦)，將網絡連線的名稱各種DIY，我就見過一個修改成"操蛋的青春"，瞬間無語！

好了，廢話不多說，直接上菜！

對于網絡連線的實際名稱，可能出現(xiàn)的情況有：
1.網卡更換/驅動升級導致名稱變更,比如本地連接2
2.系統(tǒng)語系不同導致網絡連線名稱也不同，比如簡體叫【本地連線】，而繁體卻叫【區(qū)域連線】
3.系統(tǒng)版本不同，導致命令行顯示也不同,比如ipconfig/all，簡體XP中顯示為【Ethernet adapter 本地連接:】，而簡體WIN7顯示卻是【以太網適配器 本地連接:】
4.其他不可預料的問題

那如果要編寫一個通用的IP修改腳本，必須就得考慮到以上1-3條的問題，才能提高兼容性，接近版本/簡繁語系通吃！(英文版暫未考慮)
(PS:以下代碼只為說明獲取名稱，其他一切從簡展示)：

一、先給出一個XP下簡繁體通用的獲取連線名稱的代碼

@echo off  
for /f "tokens=1,2,3 delims=: " %%i in ('ipconfig/all ^|find /i "Ethernet adapter"') do set netname=%%k 
netsh interface ip set address name="%netname%" source=static addr=192.168.1.105 mask=255.255.254.0 gateway=192.168.1.1  
pause

簡單說明：此代碼通過ipconfig/all獲取連線信息，然后抓取Ethernet adapter之后的名稱，即%%k為實際連線名稱,理論上簡繁體通用。

代碼缺點：
1.不兼容WIN7,win7使用ipconfig/all后，得到的是【乙太網路卡 區(qū)域連線:】
2.本地超過一塊網卡的時候應該會出錯(具體未實測)
適用場合：在保證單網卡和XP環(huán)境下可用不區(qū)分簡繁體使用。

二、來個XP/WIN7/簡繁體通吃的連線名稱獲取代碼(最近才幫維護人員寫的，熱乎著呢！)：

rem 以上內容略  
for /f tokens^=1^,2^ delims^=^" %%j in ('netsh interface ip show config') do (    
    if "%%j"=="介面 " ( 
    netsh interface ip set address name="%%k" source=static addr=192.168.1.105 mask=255.255.254.0 gateway=192.168.1.1   
  ) 
    if "%%j"=="接口 " ( 
    netsh interface ip set address name="%%k" source=static addr=192.168.1.105 mask=255.255.254.0 gateway=192.168.1.1  
   )  
)

簡單說明：通過netsh獲取信息，能兼容XP和WIN7；然后通過【介面】還是【接口】的區(qū)分，又能兼容簡繁體，所以是通吃代碼！

代碼缺點：暫未實現(xiàn)多網卡的區(qū)分功能，所以雙/多網卡電腦執(zhí)行此腳本，所有網卡均設置成一樣的信息，這很蛋疼！
適用范圍：只要不存在多網卡，均能使用！多網卡慎用哦~！

三、最后，再給個XP環(huán)境下加入了多網卡判斷的獲取連線名稱的腳本吧！
Ps:或許有筒子可以參考做出全兼容的腳本呢！(俺時間太緊，就不折騰啦)

rem 請使用call :getnetnme調用此模塊，然后從臨時文件"%~dp0dns.tmp"中獲取連線名稱!  
:getnetname  
setlocal enabledelayedexpansion  
set "NIC_flag=Ethernet"  
set NIC_num=0  
for /f "tokens=1,2,3,* delims=: " %%i in ('ipconfig /all') do (  
  set /a num+=1  
  if "%%i"=="%NIC_flag%" (  
    set /a num_=!num!+3,NIC_num+=1  
    set NIC_name!Nic_num!=%%k)  
  if !num! EQU !num_! set var=%%l 
  set var=!var:*:=!  
  set Desp!Nic_num!=!var!  
)  
if %NIC_num% gtr 1 ( echo 發(fā)現(xiàn)多塊網卡，請手動設置...  
     pause>nul  
     goto TCPset  
     )  
for /l %%i in (1 1 %NIC_num%) do echo !NIC_name%%i!>"%~dp0dns.tmp" 
goto :eof 

簡單說明：在代碼一的基礎上加上了網卡數(shù)量的判斷，超過一塊就提示手動設置，避免因多塊網卡設置IP出現(xiàn)問題。

代碼缺點：

1.還是未能解決多塊網卡自動設置IP的情況,請有興趣的筒子參考改進哦！
2.無法兼容WIN7

好了，以上就是獲取實際網絡連線名稱的所有代碼了，希望能幫到有需要的朋友！