古风君子以泽,完美世界辰东,辰东完美世界有声小说

主頁 > 知識庫 > 10分鐘搞定讓你困惑的 Jenkins 環(huán)境變量過程詳解

10分鐘搞定讓你困惑的 Jenkins 環(huán)境變量過程詳解

前言

Jenkins， DevOps 技術(shù)棧的核心之一，CI/CD 離不開編寫 Pipeline 腳本，上手 Jenkins ，簡單查一下文檔，你就應(yīng)該不會被 agent，stages，step 這類關(guān)鍵詞弄懵，也能很快構(gòu)建出 pipeline 的骨架

但是當向骨架中填充內(nèi)容的時候，尤其如何利用環(huán)境變量（系統(tǒng)內(nèi)置｜自定義），多數(shù)人都會變得比較混亂，浪費很多時間，本文就幫助大家快速通關(guān)環(huán)境變量

準備

如果你想一邊閱讀本文，一邊實踐，但是沒有 Jenkins 服務(wù)可用，又想快速嘗試，可以應(yīng)用 Docker 一個命令快速搭建 Jenkins 服務(wù)

docker container run --rm -p 8080:8080 -p 50000:50000 --name=jenkins -v $(pwd):/var/jenkins_home jenkins/jenkins

2021 年了，本地沒有 Docker 說不過去了，過來瞧瞧 Docker 系列是否入得了你的法眼？

打開瀏覽器輸入：localhost:8080

找到終端的臨時密碼登陸
安裝推薦的依賴
創(chuàng)建新的 Pipeline 類型的 Item
點擊左側(cè) Config，然后在頁面底部 Pipeline 部分輸入我們接下來寫的腳本進行測試就好了

就是這么簡單.....

認識 Jenkins 環(huán)境變量

Jenkins 環(huán)境變量就是通過 env 關(guān)鍵字暴露出來的全局變量，可以在 Jenkins 文件的任何位置使用

其實和你使用的編程語言中的全局變量沒有實質(zhì)差別

查看 Jenkins 系統(tǒng)內(nèi)置環(huán)境變量

Jenkins 在系統(tǒng)內(nèi)置了很多環(huán)境變量方便我們快速使用，查看起來有兩種方式：

方式一：

直接在瀏覽器中訪問 ${YOUR_JENKINS_HOST}/env-vars.html 頁面就可以，比如 http://localhost:8080/env-vars.html ，每個變量的用途寫的都很清楚

方式二

通過執(zhí)行 printenv shell 命令來獲?。?/p>

pipeline {
  agent any

  stages {
    stage("Env Variables") {
      steps {
        sh "printenv"
      }
    }
  }
}

直接 Save - Build, 在終端 log 中你會看到相應(yīng)的環(huán)境變量，并且可以快速看到他們當前的值

通常這兩種方式可以結(jié)合使用

讀取環(huán)境變量

上面我們說了 env 是環(huán)境變量的關(guān)鍵字，但是讀取 Jenkins 內(nèi)置的這些環(huán)境變量，env 關(guān)鍵字是可有可無, 但不能沒了底褲，都要使用 ${xxx} 包圍起來。以 BUILD_NUMBER 這個內(nèi)置環(huán)境變量舉例來說明就是這樣滴：

如果你在 Jenkins 文件中使用 shell 命令，使用這些內(nèi)置環(huán)境變量甚至可以不用 {}，來看一下：

pipeline {
  agent any

  stages {
    stage("Read Env Variables") {
      steps {
        echo "帶 env 的讀取方式：${env.BUILD_NUMBER}"
        echo "不帶 env 的讀取方式：${BUILD_NUMBER}"
        sh 'echo "shell 中讀取方式 $BUILD_NUMBER"'
      }
    }
  }
}

可以看到結(jié)果是一樣一樣滴，不管有幾種，記住第一種最穩(wěn)妥

內(nèi)置的環(huán)境變量雖好，但也不能完全滿足我們自定義的 pipeline 的執(zhí)行邏輯，所以我們也得知道如何定義以及使用自定義環(huán)境變量

自定義 Jenkins 環(huán)境變量

Jenkins pipeline 分聲明式（Declarative）和腳本式（imperative）寫法，相應(yīng)的環(huán)境變量定義方式也略有不同，歸納起來有三種方式：

還是看個實際例子吧：

pipeline {
  agent any

  environment {
    FOO = "bar"
  }

  stages {
    stage("Custom Env Variables") {
      environment {
        NAME = "RGYB"
      }

      steps {
        echo "FOO = ${env.FOO}"
        echo "NAME = ${env.NAME}"

        script {
          env.SCRIPT_VARIABLE = "Thumb Up"
        }

        echo "SCRIPT_VARIABLE = ${env.SCRIPT_VARIABLE}"

        withEnv(["WITH_ENV_VAR=Come On"]) {
          echo "WITH_ENV_VAR = ${env.WITH_ENV_VAR}"
        }
      }
    }
  }
}

來看運行結(jié)果：

注意：withEnv(["WITH_ENV_VAR=Come On"]) {} 這里的 = 號兩側(cè)不能有空格，必須是 key=value 的形式

一個完整的 pipeline 通常會有很多個 stage，環(huán)境變量在不同的 stage 有不同的值是很常見的，知道如何設(shè)置以及讀取環(huán)境變量后，我們還得知道如何重寫環(huán)境變量

重寫 Jenkins 環(huán)境變量

Jenkins 讓人相對困惑最多的地方就是重寫環(huán)境變量，但是只要記住下面這三條規(guī)則，就可以搞定一切了

withEnv(["WITH_ENV_VAR=Come On"]) {} 內(nèi)置函數(shù)的這種寫法，可以重寫任意環(huán)境變量
定義在 environment {} 的環(huán)境變量不能被腳本式定義的環(huán)境變量（env.key="value"）重寫
腳本式環(huán)境變量只能重寫腳本式環(huán)境變量

這三點是硬規(guī)則，沒涵蓋在這 3 點規(guī)則之內(nèi)的也就是被允許的了

三條規(guī)則就有點讓人頭大了，農(nóng)夫選豆種，舉例為證吧

pipeline {
  agent any

  environment {
    FOO = "你當像鳥飛往你的山"
    NAME = "Tan"
  }

  stages {
    stage("Env Variables") {
      environment {
       	// 會重寫第 6 行 變量
        NAME = "RGYB" 
       	// 會重寫系統(tǒng)內(nèi)置的環(huán)境變量 BUILD_NUMBER
        BUILD_NUMBER = "10" 
      }

      steps {
       	// 應(yīng)該打印出 "FOO = 你當像鳥飛往你的山"
        echo "FOO = ${env.FOO}" 
       	// 應(yīng)該打印出 "NAME = RGYB"
        echo "NAME = ${env.NAME}" 
       	// 應(yīng)該打印出 "BUILD_NUMBER = 10"
        echo "BUILD_NUMBER = ${env.BUILD_NUMBER}" 

        script {
         	// 腳本式創(chuàng)建一個環(huán)境變量
          env.SCRIPT_VARIABLE = "1" 
        }
      }
    }

    stage("Override Variables") {
      steps {
        script {
         	// 這里的 FOO 不會被重寫，違背 Rule No.2
          env.FOO = "Tara"
         	// SCRIPT_VARIABLE 變量會被重寫，符合 Rule No.3
          env.SCRIPT_VARIABLE = "2" 
        }

       	// FOO 在第 37 行重寫失敗，還會打印出 "FOO = 你當像鳥飛往你的山"
        echo "FOO = ${env.FOO}" 
       	// 會打印出 "SCRIPT_VARIABLE = 2"
        echo "SCRIPT_VARIABLE = ${env.SCRIPT_VARIABLE}" 

       	// FOO 會被重寫，符合 Rule No.1
        withEnv(["FOO=Educated"]) { 
         	// 應(yīng)該打印 "FOO = Educated"
          echo "FOO = ${env.FOO}" 
        }

       	// 道理同上
        withEnv(["BUILD_NUMBER=15"]) {
         	// 應(yīng)該打印出 "BUILD_NUMBER = 15"
          echo "BUILD_NUMBER = ${env.BUILD_NUMBER}"
        }
      }
    }
  }
}

來驗證一下結(jié)果吧

看到這，基本的設(shè)置應(yīng)該就沒有什么問題了，相信你也發(fā)現(xiàn)了，Jenkins 設(shè)置環(huán)境變量和編程語言的那種設(shè)置環(huán)境變量還是略有不同的，后者可以將變量賦值為對象，但 Jenkins 就不行，因為在 Jenkins 文件中，所有設(shè)置的值都會被當成 String，難道沒辦法應(yīng)用 Boolean 值嗎？

Jenkins 中使用 Boolean 值

如果設(shè)置一個變量為 false ，Jenkins 就會將其轉(zhuǎn)換為 "false", 如果想使用 Boolean 來做條件判斷，必須要調(diào)用 toBoolean() 方法做轉(zhuǎn)換

pipeline {
  agent any

  environment {
    IS_BOOLEAN = false
  }

  stages {
    stage("Env Variables") {
      steps {
        script {
         	// Hello 會被打印出來，因為非空字符串都會被認為是 Boolean.True
          if (env.IS_BOOLEAN) {
            echo "Hello"
          }

         	// 真正的 Boolean 比較
          if (env.IS_BOOLEAN.toBoolean() == false) {
            echo "日拱一兵"
          }
         
         	// 真正的 Boolean 
          if (!env.IS_BOOLEAN.toBoolean()) {
            echo "RGYB"
          }
        }
      }
    }
  }
}

來看運行結(jié)果：

如果你寫過 Pipeline，你一定會知道，寫 Pipeline 是離不開寫 shell 的，有些時候，需要將 shell 的執(zhí)行結(jié)果賦值給環(huán)境變量，Jenkins 也有方法支持

Shell 結(jié)果賦值給環(huán)境變量

實現(xiàn)這種方式很簡單，只需要記住一個格式：sh(script: 'cmd', returnStdout:true)

pipeline {
  agent any

  environment {
   	// 使用 trim() 去掉結(jié)果中的空格
    LS_RESULT = "${sh(script:'ls -lah', returnStdout: true).trim()}"
  }

  stages {
    stage("Env Variables") {
      steps {
        echo "LS_RESULT = ${env.LS_RESULT}"
      }
    }
  }
}

總結(jié)

關(guān)于 Jenkins 環(huán)境變量，了解這些基本上就滿足絕大多數(shù)應(yīng)用場景了，當再遇到環(huán)境變量問題時，可以回過來翻看一下了，有解決的困惑嗎？

到此這篇關(guān)于10分鐘搞定讓你困惑的 Jenkins 環(huán)境變量的文章就介紹到這了,更多相關(guān)Jenkins 環(huán)境變量內(nèi)容請搜索腳本之家以前的文章或繼續(xù)瀏覽下面的相關(guān)文章希望大家以后多多支持腳本之家！

您可能感興趣的文章:

docker環(huán)境下安裝jenkins容器的詳細教程
Docker環(huán)境搭建Jenkins在構(gòu)建任務(wù)時控制臺日志出現(xiàn)中文亂碼的問題
從零搭建docker+jenkins+node.js自動化部署環(huán)境的方法
在CentOS7上搭建Jenkins+Maven+Git持續(xù)集成環(huán)境的方法
centos下GitLab+Jenkins持續(xù)集成環(huán)境搭建(安裝jenkins)
詳解Docker下搭建Jenkins構(gòu)建環(huán)境

標簽：平頂山哈密臺州株洲商丘鶴崗綿陽鎮(zhèn)江

巨人網(wǎng)絡(luò)通訊聲明：本文標題《10分鐘搞定讓你困惑的 Jenkins 環(huán)境變量過程詳解》，本文關(guān)鍵詞 10分鐘,搞定,讓你,困惑,；如發(fā)現(xiàn)本文內(nèi)容存在版權(quán)問題，煩請?zhí)峁┫嚓P(guān)信息告之我們，我們將及時溝通與處理。本站內(nèi)容系統(tǒng)采集于網(wǎng)絡(luò)，涉及言論、版權(quán)與本站無關(guān)。